أكاديمية الصقر للتدريب

لوحة التميز الأسبوعي
العضو المتميز المشرف المتميز المراقب المتميز المدير المتميز الموضوع المتميز القسم المتميز
العضو المتميز المشرف المتميز المراقب المتميز المدير المتميز الموضوع المتميز القسم المتميز
مالك ماريه Eslam Abdullah-- لا تميز خلال هذه الفترة YasserKhalil مع أكاديمية الصقر اخفي أكوادك وعيش حياتك EvilClippy VBA Project Unviewable Protection اكسيل اسئله واجابات


اعلان هنا
ألعاب فلاش أون لاين
أعلن هنا
أعلن هنا
صفحتنا على الفيس بوك
أعلن هنا



أهلا وسهلا بك زائرنا الكريم في أكاديمية الصقر للتدريب، لكي تتمكن من المشاركة ومشاهدة جميع أقسام المنتدى وكافة الميزات ، يجب عليك إنشاء حساب جديد بالتسجيل بالضغط هنا أو تسجيل الدخول اضغط هنا إذا كنت عضواً .





إنشاء قائمة مخصصة للكليك يمين Create Custom Popup Menu

السلام عليكم ورحمة الله وبركاته إخواني في الله أقدم لكم ملف يحتوي على الطريقة لإنشاء قائمة مخصصة (قائمة تنبثق عند عمل ك ..



01-09-2019 08:39 صباحا
YasserKhalil
menu_open عضوية موثقة
مراقب عام
معلومات الكاتب ▼
تاريخ الإنضمام : 21-08-2017
رقم العضوية : 3
المشاركات : 7255
الجنس : ذكر
تاريخ الميلاد : 1-10-1978
الدعوات : 19
يتابعهم : 0
يتابعونه : 411
قوة السمعة : 20806
الاعجاب : 1454
 offline 

السلام عليكم ورحمة الله وبركاته

إخواني في الله أقدم لكم ملف يحتوي على الطريقة لإنشاء قائمة مخصصة (قائمة تنبثق عند عمل كليك يمين) ، وتحتوي على أوامر يتم تنفيذها من خلال القائمة
Dq4q3_001

الشرح داخل الملف بالتفصيل لتتمكن من التعديل على الكود بما يتناسب مع احتياجاتك

إليكم الكود الذي يوضع في موديول عادي
'الإعلان عن ثابت يحمل النص بين الأقواس ، وهو عبارة عن اسم القائمة المخصصة
Public Const mName As String = "MyPopUpMenu"

Sub DeletePopUpMenu()
'في هذا الإجراء يتم حذف القائمة المخصصة ، ووضع السطرين لتفادي حدوث خطأ
'---------------------------------------------------------------------
    On Error Resume Next
        Application.CommandBars(mName).Delete
    On Error GoTo 0
End Sub

Sub CreateDisplayPopUpMenu()
'إنشاء القائمة المخصصة ثم إظهارها
'--------------------------------
    'استدعاء الإجراء لحذف القائمة أولاً
    Call DeletePopUpMenu

    'استدعاء الإجراء لإنشاء القائمة المخصصة
    Call Custom_PopUpMenu_1

    '[MyPopUpMenu] إظهار القائمة المخصصة والمسماة
    On Error Resume Next
        Application.CommandBars(mName).ShowPopup
    On Error GoTo 0
End Sub

Private Sub Custom_PopUpMenu_1()
    '[MyPopUpMenu] بدء التعامل مع أشرطة الأدوات لإضافة شريط جديد بالاسم
    With Application.CommandBars.Add(Name:=mName, Position:=msoBarPopup, MenuBar:=False, Temporary:=True)
        '** [Button1] إضافة عنصر للقائمة الجديدة باسم
        '--------------------------------------------
        'تقوم بتغيير الشكل المرتبط بالعنصر المضاف [FaceId] الخاصية المسماة
        With .Controls.Add(Type:=msoControlButton)
            .Caption = "Button 1"
            .FaceId = 71    'Change To 41 For Example
            
            'هذا السطر هام جداً وهو المسئول عن ربط العنصر بإجراء معين أو ماكرو
            'أي عندما نقوم بعمل كليك يمين ثم تظهر القائمة المخصصة الجديدة
            'ثم نختار العنصر من القائمة يتم تنفيذ ماكرو معين واسم الماكرو
            'يوضع بين أقواس تنصيص بعد الإشارة إلى المصنف الذي يحوي الماكرو
            '['] وهو هنا المصنف الحالي أي اسم المصنف الحالي مسبوقاً ومتبوعاً بعلامة
            '[TestMacro1] ثم يليه علامة تعجب ثم اسم الماكرو الذي سيتم تنفيذه هنا
            .OnAction = "'" & ThisWorkbook.Name & "'!" & "TestMacro1"
        End With

        '** [Button2] إضافة عنصر للقائمة الجديدة باسم
        '--------------------------------------------
        With .Controls.Add(Type:=msoControlButton)
            .Caption = "Button 2"
            .FaceId = 72
            .OnAction = "'" & ThisWorkbook.Name & "'!" & "TestMacro2"
        End With

        '** [My Special Menu] إضافة عنصر للقائمة الجديدة باسم
        '----------------------------------------------------
        With .Controls.Add(Type:=msoControlPopup)
            .Caption = "My Special Menu"
            
            '== [Button 2 In Menu] والآخر باسم [Button 1 In Menu] هنا يتم إنشاء أوامر فرعية للعنصر أحدهما باسم
            With .Controls.Add(Type:=msoControlButton)
                .Caption = "Button 1 In Menu"
                .FaceId = 71
                .OnAction = "'" & ThisWorkbook.Name & "'!" & "TestMacroSpecial1"
            End With

            With .Controls.Add(Type:=msoControlButton)
                .Caption = "Button 2 In Menu"
                .FaceId = 72
                .OnAction = "'" & ThisWorkbook.Name & "'!" & "TestMacroSpecial2"
            End With
            '==--------------------------------------------------------------------------------------------==
        End With
        
        '** [Button3] إضافة عنصر للقائمة الجديدة باسم
        '--------------------------------------------
        With .Controls.Add(Type:=msoControlButton)
            .Caption = "Button 3"
            .FaceId = 73
            .OnAction = "'" & ThisWorkbook.Name & "'!" & "TestMacro3"
        End With
    End With
End Sub

Sub TestMacro1()
    MsgBox "TestMacro1"
End Sub

Sub TestMacro2()
    MsgBox "TestMacro2"
End Sub

Sub TestMacroSpecial1()
    MsgBox "TestMacroSpecial1"
End Sub

Sub TestMacroSpecial2()
    MsgBox "TestMacroSpecial2"
End Sub

Sub TestMacro3()
    MsgBox "TestMacro3"
End Sub


وهذا الكود يوضع في حدث المصنف
Private Sub Workbook_SheetBeforeRightClick(ByVal Sh As Object, ByVal Target As Range, Cancel As Boolean)
'يتم تنفيذ الكود المسئول عن إنشاء القائمة المخصصة إذا قمت بعمل كليك
'يمين في العمود الثالث في أي ورقة عمل من أوراق العمل الموجودة بالمصنف
'---------------------------------------------------------------------
    On Error Resume Next
        'إذا كان عمود الخلية الهدف التي يتم عمل كليك يمين فيها يساوي 3
        If Target.Column = 3 Then
        
            'يتم إلغاء قائمة الكليك يمين الافتراضية
            Cancel = True
    
            'استدعاء الكود الذي يقوم بإنشاء القائمة المخصصة
            Call CreateDisplayPopUpMenu
        End If
    On Error GoTo 0
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
'يوضع هذا الكود في حدث المصنف ، بحيث يتم حذف القائمة المخصصة قبل إغلاق المصنف
'----------------------------------------------------------------------------
    Call DeletePopUpMenu
End Sub


كيفية التعامل مع الملف المرفق : تم وضع كود في حدث المصنف بحيث تظهر القائمة المنبثقة عند عمل كليك يمين في العمود الثالث أي العمود C في أي ورقة من أوراق العمل بالمصنف ، قم بالنقر على أي عنصر داخل القائمة لكي يتم تنفيذ الماكرو المرتبط بهذا العنصر.

وأخيراً إليكم الملف المرفق يحتوي على الأكواد مع الشرح


لمشاهدة الروابط يلزمك التسجيل في أكاديمية الصقر للتدريب


إعداد / ياسر خليل أبو البراء
 
 


أثارت هذه المشاركة إعجاب: الصقر، نصر الإيمان، ali mohamed ali، abdulwahed catran، محمود ابو الدهب، hassona229،





01-09-2019 09:07 صباحا
مشاهدة مشاركة منفردة [1]
الصقر
menu_open عضوية موثقة
مدير المنتدى
rating
معلومات الكاتب ▼
تاريخ الإنضمام : 21-08-2017
رقم العضوية : 2
المشاركات : 1711
الجنس : ذكر
الدعوات : 16
يتابعهم : 0
يتابعونه : 573
قوة السمعة : 17638
الاعجاب : 326
موقعي : زيارة موقعي
 offline 
look/images/icons/i1.gif إنشاء قائمة مخصصة للكليك يمين Create Custom Popup Menu

الله ينور يا هندسه 3



أثارت هذه المشاركة إعجاب: YasserKhalil،


توقيع :الصقر

اخى العضو الكريم
اذا كنت ترى ان المنتدى مفيد لك
فكن سفيرا لنا بدعوة الاخرين للانضمام معنا
فالدال على الخير كفاعله



01-09-2019 09:30 صباحا
مشاهدة مشاركة منفردة [2]
YasserKhalil
menu_open عضوية موثقة
مراقب عام
معلومات الكاتب ▼
تاريخ الإنضمام : 21-08-2017
رقم العضوية : 3
المشاركات : 7255
الجنس : ذكر
تاريخ الميلاد : 1-10-1978
الدعوات : 19
يتابعهم : 0
يتابعونه : 411
قوة السمعة : 20806
الاعجاب : 1454
 offline 
look/images/icons/i1.gif إنشاء قائمة مخصصة للكليك يمين Create Custom Popup Menu
دا نورك يا غالي ..مشكور على مرورك المشرف

أثارت هذه المشاركة إعجاب: الصقر،




01-09-2019 09:53 صباحا
مشاهدة مشاركة منفردة [3]
نصر الإيمان
menu_open
عضو ماسي
rating
معلومات الكاتب ▼
تاريخ الإنضمام : 15-02-2018
رقم العضوية : 4397
المشاركات : 312
الجنس : ذكر
تاريخ الميلاد : 29-12-1985
يتابعهم : 8
يتابعونه : 3
قوة السمعة : 719
الاعجاب : 73
 offline 
look/images/icons/i1.gif إنشاء قائمة مخصصة للكليك يمين Create Custom Popup Menu
جزاك الله خيرا استاذ ياسر
دائما موضوعاتك متميزه123

أثارت هذه المشاركة إعجاب: YasserKhalil،




01-09-2019 09:58 صباحا
مشاهدة مشاركة منفردة [4]
YasserKhalil
menu_open عضوية موثقة
مراقب عام
معلومات الكاتب ▼
تاريخ الإنضمام : 21-08-2017
رقم العضوية : 3
المشاركات : 7255
الجنس : ذكر
تاريخ الميلاد : 1-10-1978
الدعوات : 19
يتابعهم : 0
يتابعونه : 411
قوة السمعة : 20806
الاعجاب : 1454
 offline 
look/images/icons/i1.gif إنشاء قائمة مخصصة للكليك يمين Create Custom Popup Menu
تسلم يا دكتور وجزيت خيراً بمثل ما دعوت لي





01-09-2019 10:12 صباحا
مشاهدة مشاركة منفردة [5]
ali mohamed ali
menu_open
مشرف على منتدى الاكسيل
rating
معلومات الكاتب ▼
تاريخ الإنضمام : 20-11-2017
رقم العضوية : 1757
المشاركات : 1210
الدولة : مصر
الجنس : ذكر
الدعوات : 1
يتابعهم : 0
يتابعونه : 52
قوة السمعة : 5709
الاعجاب : 711
 offline 
look/images/icons/i1.gif إنشاء قائمة مخصصة للكليك يمين Create Custom Popup Menu
عمل ممتاز استاذ ياسر جعله الله فى ميزان حسناتك

أثارت هذه المشاركة إعجاب: YasserKhalil،


توقيع :ali mohamed ali
{ وَقُل رَّبِّ زِدْنِي عِلْمًا }
[ كن على يقين من اعمالنا نخطئ ومن اخطائنا نتعلم ولذلك لا شي مستحيل ]
ساهم دائماً فى حل أى مشكلة او أستفسار لديك مع إضافة رد بشكره
أو دعوة لمن قدم اليك المساعدة,فالجميع هنا يعمل على مساعدة
 الاخرين لوجه الله وان تحتسب له اجر عند الله


01-09-2019 10:23 صباحا
مشاهدة مشاركة منفردة [6]
YasserKhalil
menu_open عضوية موثقة
مراقب عام
معلومات الكاتب ▼
تاريخ الإنضمام : 21-08-2017
رقم العضوية : 3
المشاركات : 7255
الجنس : ذكر
تاريخ الميلاد : 1-10-1978
الدعوات : 19
يتابعهم : 0
يتابعونه : 411
قوة السمعة : 20806
الاعجاب : 1454
 offline 
look/images/icons/i1.gif إنشاء قائمة مخصصة للكليك يمين Create Custom Popup Menu
مشكور أخي الحبيب علي على مروك العطر .. بارك الله فيك

أثارت هذه المشاركة إعجاب: ali mohamed ali،




01-09-2019 11:35 صباحا
مشاهدة مشاركة منفردة [7]
عبدالرحمن صبحى
menu_open
عضو نشيط
rating
معلومات الكاتب ▼
تاريخ الإنضمام : 24-10-2018
رقم العضوية : 8466
المشاركات : 96
الجنس : ذكر
تاريخ الميلاد : 21-4-1996
الدعوات : 3
يتابعهم : 4
يتابعونه : 0
قوة السمعة : 128
الاعجاب : 37
 offline 
look/images/icons/i1.gif إنشاء قائمة مخصصة للكليك يمين Create Custom Popup Menu
جزاك الله خيرا ...
استكمالا لموضوعك بعد ازنك طبعا هذا ملف بسيط من على النت به كل صور بالاكواد التى يمكن اضافتها فى هذا المكان FaceId = 71.   
هذا الرقم من اين اتحصل عليه من هذا الملف
تقبلوا تحياتى


لمشاهدة الروابط يلزمك التسجيل في أكاديمية الصقر للتدريب
 
 
 
  show faceids.rar   تحميل rar مرات التحميل :(11)
الحجم :(359.776) KB


أثارت هذه المشاركة إعجاب: YasserKhalil، أباالحسن،




01-09-2019 12:19 مساء
مشاهدة مشاركة منفردة [8]
YasserKhalil
menu_open عضوية موثقة
مراقب عام
معلومات الكاتب ▼
تاريخ الإنضمام : 21-08-2017
رقم العضوية : 3
المشاركات : 7255
الجنس : ذكر
تاريخ الميلاد : 1-10-1978
الدعوات : 19
يتابعهم : 0
يتابعونه : 411
قوة السمعة : 20806
الاعجاب : 1454
 offline 
look/images/icons/i1.gif إنشاء قائمة مخصصة للكليك يمين Create Custom Popup Menu
بارك الله فيك أخي الكريم عبد الرحمن ومشكور على إثرائك للموضوع
جزاك الله خيراً

أثارت هذه المشاركة إعجاب: عبدالرحمن صبحى،




01-09-2019 06:54 مساء
مشاهدة مشاركة منفردة [9]
محمود ابو الدهب
menu_open
مشرف على لغات برمجة والاكسيل
rating
معلومات الكاتب ▼
تاريخ الإنضمام : 21-08-2017
رقم العضوية : 14
المشاركات : 1238
الدولة : مصر
الجنس : ذكر
تاريخ الميلاد : 4-7-1990
الدعوات : 59
يتابعهم : 6
يتابعونه : 212
قوة السمعة : 4092
الاعجاب : 476
موقعي : زيارة موقعي
 Online 
look/images/icons/i1.gif إنشاء قائمة مخصصة للكليك يمين Create Custom Popup Menu
بارك الله فيك استاذ ياسر وجزالك الله خيرا على هذا العمل الاكثر من رائع 
دائما ما تسجل مواضيع لدى بالمرجعيات لقيمتها واهميتها فغبارك الله فيك
 

أثارت هذه المشاركة إعجاب: YasserKhalil،


توقيع :محمود ابو الدهب
لى عظيم الشرف بالانضمام لهذا الصرح العظيم
وكم أتمنى من الله
ان يعيننى ويعلمنى من علمة الواسع فهو ولي ذالك وهو على كل شي قدير

تحياتى وتقدير للجميع  محمود ابوالدهب


01-09-2019 06:55 مساء
مشاهدة مشاركة منفردة [10]
محمود ابو الدهب
menu_open
مشرف على لغات برمجة والاكسيل
rating
معلومات الكاتب ▼
تاريخ الإنضمام : 21-08-2017
رقم العضوية : 14
المشاركات : 1238
الدولة : مصر
الجنس : ذكر
تاريخ الميلاد : 4-7-1990
الدعوات : 59
يتابعهم : 6
يتابعونه : 212
قوة السمعة : 4092
الاعجاب : 476
موقعي : زيارة موقعي
 Online 
look/images/icons/i1.gif إنشاء قائمة مخصصة للكليك يمين Create Custom Popup Menu
وعارف ايه اكثر حاجه عجبانى كمان هو تغير رابط الرفع الاخر الممل ده فشكرا كمان مرة
 

أثارت هذه المشاركة إعجاب: YasserKhalil،


توقيع :محمود ابو الدهب
لى عظيم الشرف بالانضمام لهذا الصرح العظيم
وكم أتمنى من الله
ان يعيننى ويعلمنى من علمة الواسع فهو ولي ذالك وهو على كل شي قدير

تحياتى وتقدير للجميع  محمود ابوالدهب


01-09-2019 09:37 مساء
مشاهدة مشاركة منفردة [11]
khaled alborene
menu_open
عضو متميز
rating
معلومات الكاتب ▼
تاريخ الإنضمام : 22-08-2017
رقم العضوية : 16
المشاركات : 707
الجنس : ذكر
تاريخ الميلاد : 9-9-1990
الدعوات : 2
يتابعهم : 10
يتابعونه : 8
قوة السمعة : 845
الاعجاب : 68
 offline 
look/images/icons/i1.gif إنشاء قائمة مخصصة للكليك يمين Create Custom Popup Menu
فارس من فرسان الاكسل 
بارك الله فيك استاذنا ياسر 

أثارت هذه المشاركة إعجاب: YasserKhalil،




01-09-2019 10:07 مساء
مشاهدة مشاركة منفردة [12]
YasserKhalil
menu_open عضوية موثقة
مراقب عام
معلومات الكاتب ▼
تاريخ الإنضمام : 21-08-2017
رقم العضوية : 3
المشاركات : 7255
الجنس : ذكر
تاريخ الميلاد : 1-10-1978
الدعوات : 19
يتابعهم : 0
يتابعونه : 411
قوة السمعة : 20806
الاعجاب : 1454
 offline 
look/images/icons/i1.gif إنشاء قائمة مخصصة للكليك يمين Create Custom Popup Menu
جزاكم الله خيراً إخواني الكرام ومشكور على كلماتكم الطيبة وتشجيعكم الدائم لي







الكلمات الدلالية
Menu ، Popup ، Create ، Custom ، يمين ، مخصصة ، للكليك ، إنشاء ، قائمة ،


 







اخلاء مسئولية: يخلى منتدى أكاديمية الصقر للتدريب مسئوليته عن اى مواضيع او مشاركات تندرج داخل الموقع ويحثكم على التواصل معنا ان كانت هناك اى إنتهاكات تتضمن اى انتهاك لحقوق الملكية الفكرية او الادبية لاى جهة - بالتواصل معنا من خلال نموذج مراسلة الإدارة .وسيتم اتخاذ الاجراءات اللازمة.
سياسة النشر: التعليقات المنشورة لا تعبر عن رأي منتدى أكاديمية الصقر للتدريب ولا نتحمل أي مسؤولية قانونية حيال ذلك ويتحمل كاتبها مسؤولية النشر.



الساعة الآن 03:33 صباحا

أعلن هنا
أعلن هنا
أعلن هنا